Предыдущая | Следующая | Оглавление

intrinsic

Доступность

Flash Player 6.

Синтаксис

intrinsic class className  [ extends superClass ] 
              [ implements interfaceName [, interfaceName... ] ]
{
  // здесь располагается определение класса
}

Замечание: Для использования этого ключевого слова, вы должны указать ActionScript 2.0 и Flash Player 6 или более новые во вкладке Flash диалогового окна Publish Settings для вашего файла FLA. Это ключевое слово поддерживается только в случае использования во внешних файлах скриптов, но не в скриптах, написанных в окне Actions.

Описание

Ключевое слово; позволяет во время компиляции производить контроль типов для ранее определенных классов. Flash использует встроенные описания классов для контроля типов во время компиляции встроенных классов, таких как Array, Object и String. Это ключевое слово говорит компилятору, что не требуется реализация функции, и что для нее не требуется генерация байт-кода.

Ключевое слово intrinsic может быть использовано еще при объявлении переменных и функций. Flash использует это ключевое слово в файле topLevel.as для контроля типов во время компиляции для глобальных функций и свойств.

Ключевое слово intrinsic было создано специально для контроля типов во время компиляции для встроенных классов и объектов, а также для глобальных переменных и функций. Это ключевое слово не для предназначено для общего употребления, но, возможно, некоторые разработчики ищут способы контроля типов во время компиляции для ранее определенных классов, особенно если эти классы были определены с использованием ActionScript 1.0.

Пример

Следующий пример показывает как включить контроль типов во время компиляции для ранее определенных классов ActionScript 1.0. Код сгенерирует ошибку во время компиляции, потому что вызов myCircle.setRadius() отправляет строковое значение в качестве параметра, а не числовое. Вы можете избежать этой ошибки, изменив параметр на числовое значение (например, изменив "10" на 10).

// Следующий код должен быть размещен в файле Circle.as 
// который находится в вашей папке с классами:
intrinsic class Circle {
  var radius:Number;
  function Circle(radius:Number);
  function getArea():Number;
  function getDiameter():Number;
  function setRadius(param_radius:Number):Number;
}

// Это определение класса ActionScript 1.0 может быть помещено в вашем файле FLA.
// класс Circle определен с использованием ActionScript 1.0
function Circle(radius) {
  this.radius = radius;
  this.getArea = function(){
    return Math.PI*this.radius*this.radius;
  };
  this.getDiameter = function() {
    return 2*this.radius;
  };
  this.setRadius = function(param_radius) {
    this.radius = param_radius;
  }
}

// Код ActionScript 2.0, в котором используется класс Circle
var myCircle:Circle = new Circle(5);
trace(myCircle.getArea());
trace(myCircle.getDiameter());
myCircle.setRadius("10");
trace(myCircle.radius);
trace(myCircle.getArea());
trace(myCircle.getDiameter());

См. также

class, implements

Посмотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление